source: cl-darcs/trunk/configure.ac

Last change on this file was 198, checked in by Magnus Henoch, 14 years ago

Use one central makefile

File size: 1.4 KB
Line 
1AC_INIT([cl-darcs], [0.3.0], [cl-darcs-devel@common-lisp.net])
2AM_INIT_AUTOMAKE([no-dependencies foreign])
3
4my_lisp=""
5
6AC_ARG_WITH(clisp, [AS_HELP_STRING([--with-clisp], [use clisp])],
7                   [my_lisp=$my_lisp"clisp"], [])
8AC_ARG_WITH(clisp-flags, [AS_HELP_STRING([--with-clisp-flags], [clisp flags (default -i ~/.clisprc)])],
9                         [],
10                         [with_clisp_flags="-i ~/.clisprc"])
11
12AC_ARG_WITH(sbcl, [AS_HELP_STRING([--with-sbcl], [use sbcl])],
13                  [my_lisp=$my_lisp"sbcl"], [])
14AC_ARG_WITH(sbcl-flags, [AS_HELP_STRING([--with-sbcl-flags], [sbcl flags (default --disable-debugger)])],
15                        [],
16                        [with_sbcl_flags="--disable-debugger"])
17
18dnl First, try to find clisp
19if test -z "$my_lisp" -o "$my_lisp" = clisp; then
20  if test -z "$CLISP"; then
21    AC_CHECK_PROG(CLISP, clisp, clisp, [])
22  fi
23  if test -n "$CLISP"; then
24    my_lisp=clisp
25    AC_MSG_CHECKING([for clisp flags])
26    CLISP_FLAGS=$with_clisp_flags
27    AC_MSG_RESULT($CLISP_FLAGS)
28  fi
29fi
30
31dnl Then, try to find sbcl
32if test -z "$my_lisp" -o "$my_lisp" = sbcl; then
33  if test -z "$SBCL"; then
34    AC_CHECK_PROG(SBCL, sbcl, sbcl, [])
35  fi
36  if test -n "$SBCL"; then
37    my_lisp=sbcl
38    AC_MSG_CHECKING([for sbcl flags])
39    SBCL_FLAGS=$with_sbcl_flags
40    AC_MSG_RESULT($SBCL_FLAGS)
41  fi
42fi
43
44dnl Did we find any lisp?
45if test -z "$my_lisp"; then
46  AC_MSG_ERROR([no lisp found])
47fi
48
49AC_SUBST(my_lisp)
50AC_SUBST(CLISP)
51AC_SUBST(CLISP_FLAGS)
52AC_SUBST(SBCL)
53AC_SUBST(SBCL_FLAGS)
54
55AC_CONFIG_FILES([Makefile])
56AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.